#!/usr/bin/awk -f

# Copyright 2003 Jose Nazario <jose@monkey.org>
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
# 1. Redistributions of source code must retain the above copyright
#    notice, this list of conditions and the following disclaimer.
# 2. Redistributions in binary form must reproduce the above copyright
#    notice, this list of conditions and the following disclaimer in the
#    documentation and/or other materials provided with the distribution.
# 3. All advertising materials mentioning features or use of this software
#    must display the following acknowledgement:
#       This product contains software developed by Jose Nazario.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

BEGIN {
        printf("<?xml version=\"1.0\" encoding=\"ISO-8859-1\" ?>\n")
	printf("  <?xml-stylesheet type=\"text/xsl\" href=\"pfxml.xsl\" ?>\n")
        printf("  <pf source=\"pf2xml-0.22\" >\n")
}
{
        gsub("<", "\\&lt;", $0)
        gsub(">", "\\&gt;", $0)
        printf("    <packet>\n")
        printf("      <timestamp date=\"%s %s\" time=\"%s\" />\n", $1, $2, $3)
        sub(":", "", $5)
        printf("      <reason rule=\"%s %s\"", $4, $5)
        sub(":", "", $9)
        printf(" action=\"%s %s %s %s\" />\n", $6, $7, $8, $9)
        split($(10), sip, ".")
        printf("      <source ip=\"%s.%s.%s.%s\"", sip[1], sip[2], sip[3], sip[4])
        if (sip[5] != "") {
                printf(" port=\"%s\"", sip[5])
        }
        printf(" />\n")
        sub(":", "", $(12))
        split($(12), dip, ".")
        printf("      <destination ip=\"%s.%s.%s.%s\"", dip[1], dip[2], dip[3], dip[4])
        if (dip[5] != "") {
                printf (" port=\"%s\"", dip[5])
        }
        printf(" />\n")
        extra = $(13) " " $(14) " " $(15) " " $(16) " " $(17) " "  $(18) " "  $(19) " " $(20)
        printf("      <extra information=\"%s\" />\n", extra)
        printf("    </packet>\n")
}
END {
        printf("  </pf>\n")
}